pw:: BlockExtruded

An extruded block is a step-wise constructed prismatic volume originating from one or more pw::Face objects. It has a fixed number of prismatic layers in the computational K direction.

Derives From

pw::Object pw::Entity pw::GridEntity pw::Block

Summary

pw:: BlockExtruded	An extruded block is a step-wise constructed prismatic volume originating from one or more pw::Face objects.
Static Actions
create	This action creates a new extruded block object.
createFromPoints	This action, given at least one cell-type array and an extruded path of a list of lists of xyz vector values, creates an extruded block.
Static Defaults
Instance Actions
getPoint	This action gets the position of a block grid point.
setPoint	This action sets the position of a block interior grid point.
setPoints	This action extrudes the block along the path specified by the extrudePoints list.
isInteriorIndex	This action checks to see if an index corresponds to a point in the interior of the block.
getAdjacentIndices	This action returns the indices that are directly connected to the specified index.
getCellsUsingIndex	This action returns the indices that are directly connected to the specified index.
getLinearIndex	This converts a block’s ijk index to a linear index.
getPosition	This action gets the position in the defining space of the block at the given index.
getXYZ	This action gets the position of the block in model space at the given index.
getCell	This action gets the indices of the given cell.
getFace	This action gets the face at the given index or computational boundary.
addFace	This action adds a face to the block.
canReExtrude	This action returns true if the entity can be re-extruded.
getExtrusionSolverAttribute	This action gets the named extrusion solver attribute.
setExtrusionSolverAttribute	This action sets the named extrusion solver attribute.
getExtrusionBoundaryCondition	This action gets the boundary condition at a given connector region.
setExtrusionBoundaryCondition	This action sets the boundary condition at a given connector region.
Generic Extrusion Solver Attributes
Mode	This gets/sets the extrusion mode of this block.
StopAtHeight	This specifies or disables the height stop condition.
StopAtAspectRatio	This specifies or disables the max aspect ratio stop condition.
StopAtSkewAngle	This specifies or disables the min skew angle stop condition.
StopAtPositiveSkewJacobian	This enables / disables the positive skew Jacobian stop condition.
StopAtZeroJacobian	This enables / disables the zero Jacobian stop condition.
StopAtNegativeSkewJacobian	This enables / disables the negative skew Jacobian stop condition.
StopAtNegativeJacobian	This enables / disables the negative Jacobian stop condition.
DirectionFlipped	This specifies whether the extrusion direction is flipped.
PlaneAngleTolerance	This specifies the angle tolerance for determining when an arbitrary plane BC is considered equal to a Cartesian plane BC.
PlaneDeviationTolerance	This specifies the deviation tolerance for determining when an arbitrary plane BC is considered to be planar.
Translational Extrusion Solver Attributes
TranslateDirection	This gets/sets the direction vector for translate extrusion.
TranslateDistance	This gets/sets the distance for translate extrusion.
Path Extrusion Solver Attributes
PathConnectors	This gets/sets a list of connectors for the path.
PathMaximumSteps	This is the maximum number of steps available as the path extrusion is configured.
PathUseTangent	This gets/sets the flag indicating if the path extrusion should be rotated tangentally to the path connector.
Rotational Extrusion Solver Attributes
RotateAxisStart	This gets/sets the starting point of the rotation axis for rotate extrusion.
RotateAxisEnd	This gets/sets the ending point of the rotation axis for rotate extrusion.
RotateAngle	This gets/sets the angle (degrees) for rotational extrusion.
Normal Extrusion Solver Attributes
NormalInitialStepSize	This gets/sets the size of the first marching step to value.
NormalMaximumStepSize	This gets/sets the upper limit for the marching step size.
NormalMinimumStepSize	This gets/sets a upper limit for the marching step size.
NormalCornerFactor	This gets/sets a scale factor for reducing the local marching step in convex regions and increasing the marching step size in concave regions.
NormalDirectionRelaxation	The normals in the marching direction are smoothed locally using a LaPlace filter.
NormalDirectionRelaxationIterations	The normals in the marching direction are smoothed locally using a Lalace filter.
NormalStepSizeRelaxation	This gets/sets the relaxation smoothing factor.
NormalStepSizeRelaxationIterations	This gets/sets the number of marching iterations for the LaPlace filter.
NormalFeatureSmoothing	This specifies whether knife edge features are smoothed.
NormalQualitySmoothing	This enables/disables normal smoothing based on a quality metric.
NormalInteriorOnlySmoothing	This enables/disables interior only quality based smoothing.
NormalMaximumIterationsSmoothing	This specifies/retrieves the maximum number of smoothing iterations.
NormalBlendExponentSmoothing	This specifies/retrieves the blend exponent for smoothing.
Spacing Extrusion Solver Attributes
SpacingMode	This gets/sets the spacing configuration for the extrusion.
SpacingGrowthFactor	This specifies how the marching step size will grow from its initial value.
SpacingConnectors	This gets/sets the collection of connector-object and subconnector-index pairs that specify how the marching step size will grow from its initial value.

createFromPoints

pw::BlockExtruded createFromPoints ?-triangles tricellArray? ?-quadrilaterals quadCellArray? ?-splitAngle angle? ?-splitMultiLoop? extrudePoints

This action, given at least one cell-type array and an extruded path of a list of lists of xyz vector values, creates an extruded block. No extruded block will be created if the cell-type array(s) define more than one face.

Parameters

The following optional cell array parameters (at least one of which is required) are each a list of lists. The sub-lists represent indices into the points list for each vertex of the particular cell. For example, there are 3 vertices for each triangle. Therefore, the ‘triCellArray’ will consist of N sub-lists, where each sub-list has 3 indices representing the three vertices of the triangle. The indices are 1-based. These arrays describe the base face layer of the block.

-triangles triCellArray	This optional parameter is a list of cells, where each cell list is 3 integers (one element for each triangle vertex, each of which refers to that index in the points array).
-quadrilaterals quadCellArray	This optional parameter is a list of cells, where each cell list is 4 integers (one element for each quadrilateral vertex, each of which refers to that index in the points array).

The next two parameters are additional optional parameters, neither of which is required. They are used when creating the domain(s) for the base face of the new extruded block.

-splitAngle splitAngle	this optional float parameter specifies an angle at which to split connectors.
-splitMultiloop	this optional flag indicates that domains with more than 1 loop should be split.

This is a required parameter

extrudePoints

This required parameter is a list of a list of xyz vectors to be used to define the base layer (face) and extrude path. The first sub-list defines the points used by the cell array(s) to create the base face layer. The subsequent lists describe each subsequent layer of the extrusion, must have the same number of points as the base face layer, and must be mappable to the base face layer points.

Returns

This action returns the newly created pw::BlockExtruded block.

Example

This example shows how a rotated extruded block can be created from a set of points and quadrilateral connectivity.

Code

# Rotate a list of points an angle about an axis
proc rotateVec3 { pts angle axis origin } {
  set matrix [pwu::Transform rotation -anchor $origin $axis $angle]
  set rotPts [list]
  foreach pt $pts {
    set x0 [lindex $pt 0]
    set y0 [lindex $pt 1]
    set z0 [lindex $pt 2]
    set x [expr {$x0 * [lindex $matrix 0] + $y0 * [lindex $matrix 4] \
      + $z0 * [lindex $matrix 8] + [lindex $matrix 12]}]
    set y [expr {$x0 * [lindex $matrix 1] + $y0 * [lindex $matrix 5] \
      + $z0 * [lindex $matrix 9] + [lindex $matrix 13]}]
    set z [expr {$x0 * [lindex $matrix 2] + $y0 * [lindex $matrix 6] \
      + $z0 * [lindex $matrix 10] + [lindex $matrix 14]}]
    set w [expr {$x0 * [lindex $matrix 3] + $y0 * [lindex $matrix 7] \
      + $z0 * [lindex $matrix 11] + [lindex $matrix 15]}]
    set rotPt [pwu::Vector3 divide [pwu::Vector3 set $x $y $z] $w]
    lappend rotPts $rotPt
  }
  return $rotPts
}

proc getPoints {idim jdim} {
  set pts [list]
  for {set j 0} {$j < $jdim} {incr j} {
    for {set i 0} {$i < $idim} {incr i} {
       lappend pts [pwu::Vector3 set 0 $i $j]
    }
  }
  return $pts
}

proc getQuads {idim jdim} {
  set quads [list]
  for {set j 1} {$j < $jdim} {incr j} {
    for {set i 1} {$i < $idim} {incr i} {
       set n1 [expr {$jdim * ($j - 1) + $i}]
       set n0 [expr {$n1 - 1}]
       set n2 [expr {$jdim * $j + $i} ]
       set n3 [expr {$n2 - 1}]
       lappend quads [list $n0 $n1 $n2 $n3]
    }
  }
  return $quads
}

set idim 10
set jdim 10
set origin [list 0 -10 0]
set rotAxis [pwu::Vector3 set 0 0 1]
set totalAngle -90.
set numLayers 21

set pts [getPoints $idim $jdim]
set quads [getQuads $idim $jdim]

set extPts [list]
lappend extPts $pts
for {set i 1} {$i < $numLayers} {incr i} {
  set angle [expr {$totalAngle * (double($i) / double($numLayers - 1))}]
  lappend extPts [rotateVec3 $pts $angle $rotAxis $origin]
}

# Create extruded block
set extBlk [pw::BlockExtruded createFromPoints -quadrilaterals $quads $extPts]

setPoints

$block setPoints extrudePoints

This action extrudes the block along the path specified by the extrudePoints list.

Parameters

extrudePoints

This required parameter is a list of a list of xyz vectors that define the extrude path. These points must be mappable to the points in the block’s face.

Returns

This action returns nothing.

Example

This example shows how a rotated extruded block can be created from a set of points and triangle connectivity.

Code

# Rotate a list of points an angle about an axis
proc rotateVec3 { pts angle axis origin } {
  set matrix [pwu::Transform rotation -anchor $origin $axis $angle]
  set rotPts [list]
  foreach pt $pts {
    set x0 [lindex $pt 0]
    set y0 [lindex $pt 1]
    set z0 [lindex $pt 2]
    set x [expr {$x0 * [lindex $matrix 0] + $y0 * [lindex $matrix 4] \
      + $z0 * [lindex $matrix 8] + [lindex $matrix 12]}]
    set y [expr {$x0 * [lindex $matrix 1] + $y0 * [lindex $matrix 5] \
      + $z0 * [lindex $matrix 9] + [lindex $matrix 13]}]
    set z [expr {$x0 * [lindex $matrix 2] + $y0 * [lindex $matrix 6] \
      + $z0 * [lindex $matrix 10] + [lindex $matrix 14]}]
    set w [expr {$x0 * [lindex $matrix 3] + $y0 * [lindex $matrix 7] \
      + $z0 * [lindex $matrix 11] + [lindex $matrix 15]}]
    set rotPt [pwu::Vector3 divide [pwu::Vector3 set $x $y $z] $w]
    lappend rotPts $rotPt
  }
  return $rotPts
}

proc getPoints {idim jdim} {
  set pts [list]
  for {set j 0} {$j < $jdim} {incr j} {
    for {set i 0} {$i < $idim} {incr i} {
       lappend pts [pwu::Vector3 set 0 $i $j]
    }
  }
  return $pts
}

proc getQuads {idim jdim} {
  set quads [list]
  for {set j 1} {$j < $jdim} {incr j} {
    for {set i 1} {$i < $idim} {incr i} {
       set n1 [expr {$jdim * ($j - 1) + $i}]
       set n0 [expr {$n1 - 1}]
       set n2 [expr {$jdim * $j + $i} ]
       set n3 [expr {$n2 - 1}]
       lappend quads [list $n0 $n1 $n2 $n3]
    }
  }
  return $quads
}

set idim 10
set jdim 10
set origin [list 0 -10 0]
set rotAxis [pwu::Vector3 set 0 0 1]
set totalAngle -90.
set numLayers 21

set pts [getPoints $idim $jdim]
set quads [getQuads $idim $jdim]

set doms [pw::DomainUnstructured createFromPoints -quads $quads $pts]

# Create face
set face [pw::FaceUnstructured createFromDomains $doms]
set facePntCnt [$face getPointCount]

set facePnts [list]
for {set i 1} {$i <= $facePntCnt} {incr i} {
  lappend facePnts [$face getPoint $i]
}

# Create extruded block
set extBlk2 [pw::BlockExtruded create]

# Add face
$extBlk2 addFace $face

set extPts [list]
lappend extPts $facePnts
for {set i 1} {$i < $numLayers} {incr i} {
  set angle [expr {$totalAngle * (double($i) / double($numLayers - 1))}]
  lappend extPts [rotateVec3 $facePnts $angle $rotAxis $origin]
}

# Create extruded block by setPoints
$extBlk setPoints $extPts

getCellsUsingIndex

$block getCellsUsingIndex ?-linear? < index | ijk_index >

This action returns the indices that are directly connected to the specified index.

Parameters

-linear	If this optional flag is specified, the results will be a list of integer linear indices regardless of the input form. This is the default option and is present to maintain consistency with the form of the command used for pw::BlockStructured and pw::BlockExtruded objects.
index	This optional parameter is the integer index of the target grid point; [1, number of points].
ijk_index	This optional parameter is the ijk index of the point to get.

Information

Either index or ijk_index must be specified.

Returns

This action returns a list of cell entries using the specified point. Each cell entry will be a list of point indices comprising the cell. The form of each point index will be the same as the input form. If index is used or -linear is specified, each cell entry will be a list of integer linear indices. If ijk_index is used and -linear is not specified, each cell entry will be a list of ijk indices.

getPosition

$block getPosition ?-grid? < index | ijk_index >

This action gets the position in the defining space of the block at the given index.

Parameters

-grid	This optional flag is notification to get the position at a grid point. This is the default.
index	This optional parameter is the integer linear index of the point to get.
ijk_index	This optional parameter is the ijk index of the point to get.

Returns

This action returns a point giving the position on the block (may be in the form “u v dbentity”).

Information

Either index or ijk_index must be specified.

Even though it is not needed, the -grid switch is included here to be consistent with the other grid entity getPosition methods. The following calls are equivalent:

$extblk1 getPosition -grid [list 1 2 3]
$extblk1 getPosition [list 1 2 3]

getXYZ

$block getXYZ ?-grid? < index | ijk_index >

This action gets the position of the block in model space at the given index.

Parameters

-grid	This optional flag is notification to get the position at a grid point. This is the default.
index	This optional parameter is the integer linear index of the point to get.
ijk_index	This optional parameter is the ijk index of the point to get.

Returns

This action returns an XYZ vector.

Information

Either index or ijk_index must be specified.

Even though it is not needed, the -grid switch is included here to be consistent with the other grid entity getPosition methods. The following calls are equivalent:

$extblk1 getXYZ -grid 22
$extblk1 getXYZ 22

getExtrusionBoundaryCondition

$block getExtrusionBoundaryCondition edge_con_pair

This action gets the boundary condition at a given connector region.

Parameters

edge_con_pair

This required parameter is a two-element list consisting of the integer edge index and the integer connector index within the edge.

Returns

This action returns the string name of the boundary condition, except in the case of DatabaseConstrained and AdjacentGrid. In those cases, this action returns a list containing the name of the boundary condition and the pertinent entities (pw::DatabaseEntity or pw::DomainStructured).

Boundary Conditions

ConstantX	Grid points on the front maintain a constant X coordinate value.
ConstantY	Grid points on the front maintain a constant Y coordinate value.
ConstantZ	Grid points on the front maintain a constant Z coordinate value.
FloatingX	Grid points on the front maintain a constant Y and Z coordinate value (only X floats).
FloatingY	Grid points on the front maintain a constant Z and X coordinate value (only Y floats).
FloatingZ	Grid points on the front maintain a constant X and Y coordinate value (only Z floats).
ArbitraryPlane	Determines the plane in which the connector lies and constrains the grid points to that plane as the front advances.
DatabaseConstrained	Grid points in the front are projected to one or more database surfaces using closest point projection method.
AdjacentGrid	Grid points in the front are constrained to match the grid points in an existing domain.

pw:: BlockExtruded

Derives From

Static Actions

create

Parameters

Returns

See Also

createFromPoints

Parameters

This is a required parameter

Returns

See Also

Example

Static Defaults

Instance Actions

getPoint

Parameters

Information

Returns

setPoint

Parameters

Information

Returns

Information

setPoints

Parameters

Returns

Example

isInteriorIndex

Parameters

Information

Returns

getAdjacentIndices

Parameters

Information

Returns

getCellsUsingIndex

Parameters

Information

Returns

getLinearIndex

Parameters

Returns

getPosition

Parameters

Returns

Information

See Also

getXYZ

Parameters

Returns

Information

See Also

getCell

Parameters

Information

Returns

getFace

Parameters

Information

Returns

addFace

Parameters

Returns

canReExtrude

Parameters

Returns

Example

getExtrusionSolverAttribute

Parameters

Returns

See Also

setExtrusionSolverAttribute

Parameters

Returns

See Also

getExtrusionBoundaryCondition

Parameters

Returns

Boundary Conditions